Unity製ノベルゲーム制作キット。iphone・Android アプリ化対応。

クイック検索

ジョーカースクリプト タグリファレンス

KAG3/吉里吉里と親和性の高いタグ構成になっています。また、順次対応タグを拡充する予定です

基本

[ ] で囲まれた部分がタグになります。
@で始まる行も、タグとして認識しますが、1行で記述しなければなりません
;(セミコロン)で始まる行はコメントとして扱われます。
複数行にわたってコメントにする場合は、/* からはじめて */ で 閉じることでコメントになります。 



[anim]イメージのアニメーション

newしている画像をアニメーションさせることができます。
tagを指定することで複数ファイルを一斉にアニメーションさせることもできます。

パラメータ名必須 デフォルト説明
name × 識別するための名前を指定します
tag × タグ名を指定できます
time × 1 秒数を指定します。指定した秒数をかけてアニメーションを行います
type × linear アニメーションの演出を指定できます。指定できるtypeについては http://www.robertpenner.com/easing/easing_demo.html が参考になります
wait × true アニメーションの完了を待つかどうかを指定します。trueで完了まで待ちます。
x × アニメーション先のX座標を指定します。
y × アニメーション先のY座標を指定します。
scale × 大きさをアニメーションできます。拡大率を指定します。例えば2.0 だと2倍の大きさになります。

サンプルコード

;画像の定義
[image_new name="test" storage="test"]

;イメージを表示
[image_show name="test" ]

;X=3 Y=3に5秒かけてアニメーションしながら移動します
[anim name="test" time=5 x=3 y=3]


アニメーション関連




[playbgm]BGM再生

BGMを再生します。
対応ファイル形式は .aif、.wav、.mp3、 .oggファイルです

パラメータ名必須 デフォルト説明
storage 再生する音楽ファイルを指定します
time × 0 音が最大ボリュームになるまでにかかる秒数をしていします。つまり値をおおきくすると長い時間をかけて徐々に音楽が再生されます
vol × 1 再生時のボリュームを指定します(0〜1.0)1が最大です。
wait × true trueを指定することでtimeで指定した時間が完了するまで次の処理に移動しなくなります。
next × true falseを指定すると次の処理に移動することなく、音楽を再生します。

サンプルコード

;BGMの再生
[playbgm wait=false time=1 storage="music"]

オーディオ関連




[stopbgm]BGM停止

BGMを停止します。
storageを指定することで複数再生中の場合特定の音源のみを停止することができます。
ファイルはbgmフォルダ以下に格納してください

パラメータ名必須 デフォルト説明
storage × 再生する音楽ファイルを指定します
time × 1 音が停止するまでにかかる秒数を指定します。徐々に音楽が停止していきます
wait × true trueを指定することでtimeで指定した時間が完了するまで次の処理に移動しなくなります。

サンプルコード

;BGMの停止
[stopbgm]

オーディオ関連




[playse]効果音再生

効果音を再生します。
対応ファイル形式は .aif、.wav、.mp3、 .oggファイルです
ファイルはsoundフォルダ以下に格納してください

パラメータ名必須 デフォルト説明
storage 再生する音楽ファイルを指定します
vol × 1 効果音の音量を指定します(0〜1.0)の間で指定してください
wait × true trueを指定することでtimeで指定した時間が完了するまで次の処理に移動しなくなります。
loop × false trueを指定すると音楽を繰り返し再生します。

サンプルコード

;効果音の再生
[playse storage="button"]


オーディオ関連




[stopse]効果音停止

効果音を停止します。

パラメータ名必須 デフォルト説明
storage × 再生する音楽ファイルを指定します
time × 0 指定した秒数をかけて効果音が停止します
loop × wait 効果音が停止するまで待ちます

サンプルコード

;効果音の再生
[stopse]

オーディオ関連




[bg_new]背景を作製

新しく背景を定義します。
通常は1度だけ定義しておくことで場面の切り替えなどが実現できます。
複数の背景を定義して組み合わせることで高度な演出を実現することも可能です。
画像ファイルはbackgroundフォルダ以下に配置してください。

パラメータ名必須 デフォルト説明
name × 識別するための名前を指定します
storage 画像ファイルを指定します。ファイルはbackgroundフォルダに格納してください
tag × タグ名を指定できます
layer × Default 表示レイヤです。通常は変更しないでください
sort × 0 同一レイヤ内の表示順を整数で指定してください
x × 0 中心からのx位置を指定します
y × 0 中心からのy位置を指定します
scale_x × 1 X方向へのイメージの拡大率を指定します。
scale_y × 1 Y方向へのイメージの拡大率を指定します。
scale × イメージの拡大率を指定します。つまり2と指定すると大きさが2倍になります

サンプルコード

;背景を定義
[bg_new storage="room"]

;背景を表示します
[bg_show ]

;名前を指定して表示することも可能
[bg_new name="test" storage="room"]

;背景を表示します
[bg_show name="test" ]

イメージ関連




[bg_show]背景を表示します。

bg_newで定義した背景を表示します

パラメータ名必須 デフォルト説明
name × 識別するための名前を指定します
tag × 識別するためのタグを指定します
x × 中心からのx位置を指定します
y × 中心からのy位置を指定します
time × 1 表示にかかる時間を秒で指定します。デフォルトは1(秒)です
wait × true 表示の完了を待つかどうかを true false で指定します。デフォルトは true です。
type × linear 表示のされ方を指定できます。

サンプルコード

;背景を定義
[bg_new storage="room"]

;背景を表示します
[bg_show ]

イメージ関連




[bg_hide]背景を非表示にします

bg_newで定義した背景を非表示にします。

パラメータ名必須 デフォルト説明
name × 識別するための名前を指定します
tag × 識別するためのタグを指定します
time × 1 非表示にかかる時間を秒で指定します。デフォルトは1(秒)です
wait × true 非表示の完了を待つかどうかを true false で指定します。デフォルトは true です。
type × linear 非表示のされ方を指定できます。デフォルトはlinear です。

サンプルコード

[bg_show ]
[bg_hide wait=false]


イメージ関連




[bg_mod]背景を変更します

bg_newで定義した画像の情報を変更します。

パラメータ名必須 デフォルト説明
name × 識別するための名前を指定します
storage × 画像ファイル名を直接していできます。フォルダはbackgroundフォルダ 以下を参照します。
time × 1 変更にかかる時間を秒で指定します。デフォルトは1(秒)です
wait × true 変更を待つかどうかを true false で指定します。デフォルトは true です。
type × linear 変更のされ方を指定できます。デフォルトはlinear です。

サンプルコード
;name ロゴを表示
[bg_show ]

;背景を切り替え
[bg_mod storage="other_bg"]

イメージ関連




[bg_remove]背景の削除

背景定義を削除します。
使用しなくなった背景を削除することにより
メモリを節約することでゲームが快適に動作することができます。
このタグで背景を削除した場合、再度表示するときは
新たに[bg_new]する必要があります。

パラメータ名必須 デフォルト説明
name × 削除する背景を指定します。

サンプルコード
[bg_remove name="room"]

イメージ関連




[button_new]ボタンの定義

画面にボタンを配置します
ボタンに対してイベントを関連付けて使用してください。

■anchor に指定できる値
LowerCenter
LowerLeft
LowerRight
MiddleCenter
MiddleLeft
MiddleRight
UpperCenter
UpperLeft
UpperRight
MiddleCenter


パラメータ名必須 デフォルト説明
name 識別するための名前を指定します
storage ボタンに使用する画像を指定します
val × ボタンにテキストを載せたい場合、文字列を指定します
tag × タグ名を指定できます
layer × Default 表示させるレイヤを指定します。画面の背面から順に、background,Default,character,message,front が指定できます。デフォルトはDefaultが指定されます
sort × 0 同一レイヤ内の表示順を整数で指定してください
x × 0 中心からのx位置を指定します
y × 0 中心からのy位置を指定します
z × -3.2 中心からのz位置を指定します
scale_x × 1 X方向へのボタンの拡大率を指定します。
scale_y × 1 Y方向へのボタンの拡大率を指定します。
width × ボタンの横幅を指定します(必ずheightとセットで指定します)
height × ボタンの高さを指定します(必ずwidthとセットで指定します)
scale × ボタンの拡大率を指定します。つまり2と指定すると大きさが2倍になります
anchor × MiddleCenter テキストの位置を指定できます
color × FFFFFF テキストの色を16進数形式で指定します
fontsize × 24 フォントサイズを指定します
cut × 数値を指定します。指定した文字数でカットします。

サンプルコード
@button_new name="test" anchor="MiddleLeft" val="ボタンのテキスト内容" x=100 y=100

;テキストの表示
@button_show name="test"

;imageタグでも表示することができます
@button_show name="test"


ボタン関連




[button_pos]ボタンの表示位置設定

button_newで定義したボタンの表示位置を指定することができます。

パラメータ名必須 デフォルト説明
name 識別するための名前を指定します
x × 中心からのx位置を指定します
y × 中心からのy位置を指定します

サンプルコード
[button_pos name="logo" x=0 y=0.5 ]

ボタン関連




[button_show]ボタンを表示します。

button_newで定義したボタンを表示します

パラメータ名必須 デフォルト説明
name × 識別するための名前を指定します
tag × 識別するためのタグを指定します
x × 中心からのx位置を指定します
y × 中心からのy位置を指定します
z × 中心からのz位置を指定します
time × 1 表示にかかる時間を秒で指定します。デフォルトは1(秒)です
wait × true 表示の完了を待つかどうかを true false で指定します。デフォルトは true です。
type × linear 表示のされ方を指定できます。デフォルトはlinear です。

サンプルコード

;ロゴを表示
[button_show name=logo ]

;tagを指定して複数画像を一斉に表示することも可能
[button_show tag=logo time=3 wait=false]

ボタン関連




[button_hide]ボタンを非表示にします

button_newで定義した画像を非表示にします。

パラメータ名必須 デフォルト説明
name × 識別するための名前を指定します
tag × 識別するためのタグを指定します
time × 1 非表示にかかる時間を秒で指定します。デフォルトは1(秒)です
wait × true 非表示の完了を待つかどうかを true false で指定します。デフォルトは true です。
type × linear 非表示のされ方をしていできます。デフォルトはlinear です。

サンプルコード
;name ボタンを表示
[button_show name=logo ]

;tagを指定して複数画像を一斉に表示することも可能
[button_hide name=logo time=3 wait=false]


ボタン関連




[button_mod]ボタンを変更します

button_newで定義したボタンの情報を変更します。

パラメータ名必須 デフォルト説明
name 識別するための名前を指定します
val × テキスト文字列を入力します
time × 1 変更にかかる時間を秒で指定します。デフォルトは1(秒)です
wait × true 変更を待つかどうかを true false で指定します。デフォルトは true です。
type × linear 変更のされ方を指定できます。デフォルトはlinear です。

サンプルコード
;ロゴを表示
[button_show name=logo ]

[button_mod name=logo val="変更後テキスト"]


ボタン関連




[button_remove]ボタンの削除

ボタン定義を削除します。

パラメータ名必須 デフォルト説明
name 削除するテキストオブジェクト名

サンプルコード
[button_remove name="yuko"]

ボタン関連




[chara_new]キャラクター定義

キャラクターを新しく定義します。

パラメータ名必須 デフォルト説明
name 識別するための名前を指定します
storage 画像ファイルを指定します
tag × タグ名を指定できます。
layer × Default 表示させるレイヤを指定します。デフォルトはcharacterが採用されます
sort × 0 同一レイヤ内の表示順を整数で指定してください 数値が小さいほど背面に表示されます
x × 0 表示位置について中心からのx位置を指定します
y × 0 表示位置について中心からのy位置を指定します
scale × キャライメージの拡大率を指定します。つまり2と指定すると大きさが2倍になります
jname × キャラクター名前欄に表示する名前を設定しておくことができます。
jcolor × jnameの表示色を指定することができます。

サンプルコード
[chara_new name="yuko" tag="scene1" jname="優子" ]

#yuko
上記のように書くことでキャラクター名前欄に優子を表示することができる

キャラクター関連




[chara_pos]キャラクター位置設定

キャラクター画像の表示位置を指定することができます。

パラメータ名必須 デフォルト説明
name 位置変更する対象の名前を指定します
x × 中心からのx位置を指定します
y × 中心からのy位置を指定します
scale_x × X方向へのイメージの拡大率を指定します。
scale_y × Y方向へのイメージの拡大率を指定します。
scale × イメージの拡大率を指定します。つまり2と指定すると大きさが2倍になります

サンプルコード
[chara_pos name="name" x=2.5 y=1.5 ]

キャラクター関連




[chara_show]キャラクター登場。

chara_newで定義したキャラクターを登場させます。

パラメータ名必須 デフォルト説明
name × 表示させる対象の名前を指定します
tag × 識別するためのタグを指定します
x × 中心からのx位置を指定します
y × 中心からのy位置を指定します
z × 中心からのz位置を指定します
time × 1 表示にかかる時間を秒で指定します。デフォルトは1(秒)です
wait × true 表示の完了を待つかどうかを true false で指定します。デフォルトは true です。
type × linear 表示のされ方を指定できます。デフォルトはlinear です。

サンプルコード

[chara_new name="yuko" storage="yuko"]
;キャラクターを表示
[chara_show name=yuko ]

;tagを指定して複数キャラを一斉に表示することも可能
[chara_show tag=chara time=3 wait=false]


キャラクター関連




[chara_hide]キャラクター退場

画面に表示しているキャラクターを非表示にします。
chara_hideタグで非表示にしたキャラクターは
いつでもchara_showで再登場させることができます。

パラメータ名必須 デフォルト説明
name × 識別するための名前を指定します
tag × 識別するためのタグを指定します
time × 1 非表示にかかる時間を秒で指定します。デフォルトは1(秒)です
wait × true 非表示の完了を待つかどうかを true false で指定します。デフォルトは true です。
type × linear 非表示のされ方をしていできます。デフォルトはlinear です。

サンプルコード

;キャラクターを表示する
[chara_show name=yuko ]

;キャラクターを退場させる
[chara_hide name=yuko time=3 wait=false]

;キャラクターをもう一度表示
[chara_show name=yuko ]


キャラクター関連




[chara_face]キャラクター表情登録

chara_faceで表情を登録しておくことで
それ以後は表情名を指定するだけで画像を切替える事ができるようになります。

パラメータ名必須 デフォルト説明
name 識別するための名前を指定します
face 登録する表情名を指定します
storage 画像ファイル名を指定します。ファイルはcharacterフォルダ以下に配置してください

サンプルコード

;キャラクター定義
[chara_new name="hiro" storage="chara" scale="1.2"]

;キャラクターの表情登録
[chara_face name="hiro" face="no1" storage=angry ]
[chara_face name="hiro" face="no2" storage=sad ]

;キャラクターの表示
[chara_show name="hiro" ]

;キャラクターの表情変更
[chara_mod name="hiro" face="no1"]

;最初に登録した表情にはdefaultと指定することで変更できる
[chara_mod name="hiro" face="default" ]


キャラクター関連




[chara_mod]キャラクター変更

定義済みのキャラクター情報を変更します。

パラメータ名必須 デフォルト説明
name 識別するための名前を指定します
face × image_face で指定した表情名を指定できます
storage × 画像ファイル名を直接指定できます。フォルダはcharacter 以下を参照します。
time × 1 変更にかかる時間を秒で指定します。デフォルトは1(秒)です
wait × true 変更を待つかどうかを true false で指定します。デフォルトは true です。
type × linear 変更のされ方を指定できます。デフォルトはlinear です。

サンプルコード

;キャラクター定義
[chara_new name="hiro" storage="chara" scale="1.2"]

;キャラクターの表情登録
[chara_face name="hiro" face="no1" storage=angry ]
[chara_face name="hiro" face="no2" storage=sad ]

;キャラクターの表示
[chara_show name="hiro" ]

;キャラクターの表情変更
[chara_mod name="hiro" face="no1"]

;直接画像ファイルを指定して変更することも可能
[chara_mod name="hiro" storage="test"]


キャラクター関連




[chara_remove]キャラクター削除

キャラクター定義を削除します。
使用しなくなったキャラクターを削除することにより
メモリを節約することでゲームが快適に動作することができます。
このタグでキャラクターを削除した場合、再度表示するときは
新たに[chara_new]する必要があります。

パラメータ名必須 デフォルト説明
name × 削除するキャラクターをchara_new の時に設定したnameを指定します。all と入力することですべてのキャラクターを削除することができます。

サンプルコード
[chara_remove name="yuko"]

キャラクター関連




[clickable]クリッカブル表示

画面にクリッカブル領域を配置することができます。
クリッカブルは画面をタッチすることでイベントを発生させることができる透明の領域のことです。
脱出ゲームなどで多用される技術です

開発中はパラメータの透明度を上げておいて、見えるようにして開発するのがよいでしょう。

パラメータ名必須 デフォルト説明
name 表示するクリッカブルの名前を指定してください
tag × タグ名称を指定します
layer × Default クリッカブルを配置するレイヤを設定できます
sort × 10 クリッカブルの表示順を指定できます。数値が大きいほど全面に配置されます
a × 0.3 クリッカブルの透明度を指定できます 0〜1.0 で0が完全に透明を表します
x × 0 表示位置のX座標を指定します
y × 0 表示位置のY座標を指定します
scale_x × 1 クリッカブルの横幅の拡大率を指定できます。
scale_y × 1 クリッカブルの縦幅の拡大率を指定できます。

サンプルコード

;クリッカブルを設定
[clickable name="click1" tag=clickable a=0 scale_x=2.37 scale_y =0.55 x=0.94 y=0.8 ]
[clickable name="click2" tag=clickable a=0 scale_x=0.4 scale_y=0.3 x=3.41 y=1.83 ]
[clickable name="click3" tag=clickable a=0 scale_x=1.31 scale_y=1.18 x=-6.08 y=1.52 ]

;クリックされた時にイベントを設定
[evt name="click1" target="*clickable1"]
[evt name="click2" target="*clickable2"]
[evt name="click3" target="*clickable3"]

クリッカブル関連




[story]テキスト表示

テキストを表示するタグです。
通常シナリオはタグを使用せずに記述しますが
タグを使用することも可能です

パラメータ名必須 デフォルト説明
val 表示するテキストを指定します

サンプルコード

;下記2つは全く同一の動作
ストーリーを記述[p]
[story val="ストーリーを記述"]

メッセージ関連




[r]改行する

改行をします。

パラメータ名必須 デフォルト説明
指定できるパラメータはありません

サンプルコード

テキスト表示[r]
2行目テキスト表示[r]
3行目テキスト表示[r]

メッセージ関連




[l]クリック待ち

このタグの位置でクリック待ちを行います

パラメータ名必須 デフォルト説明
指定できるパラメータはありません

サンプルコード
いち[l]に[l]さん[l][r]


メッセージ関連




[p]改ページクリック待ち

改ページをともなうクリック待ちを行います

パラメータ名必須 デフォルト説明
指定できるパラメータはありません

サンプルコード
テキスト表示[p]
1度クリックを待って[l]
2度めのクリックで改ページ[p]

メッセージ関連




[cm]改ページクリック無し

このタグに到達した時点でメッセージをクリアします

パラメータ名必須 デフォルト説明
指定できるパラメータはありません

サンプルコード

テキスト表示[p]
ここはクリック待たないで消える[cm]
ここはクリック待ち[p]

メッセージ関連




[evt]イベントの登録

画面上のイメージに対してイベントを登録することができます。
イベントが発生した際は指定した場所へジャンプをおこないます。
ジャンプ先は一方通行でスタックが残りません(return で戻れない)
イベントが発生した場所に戻りたい場合はジャンプ先でevt変数に呼び出し元情報が格納されているのでそれを活用します
evt.caller_index = イベントが発生した箇所のindexが格納されています
evt.caller_file = イベントが発生したファイル名が格納されています
evt.caller_name = イベントが発生したイメージのnameが格納されています。

パラメータ名必須 デフォルト説明
name × イベントを登録するnameを指定します
tag × 指定タグに対してまとめてイベントを登録することができます
act × click 補足するイベントの種類をしていします。例えばクリックなどを指定できます。
file × イベントが発生した際にジャンプするファイル名を記述します。省略された場合は、現在のファイル名と解釈されます
target × イベントが発生した際にジャンプする先のラベル名を指定できます。省略されている場合は先頭位置からと解釈されます

サンプルコード

[button_new name="button" text="ボタンです" ]
[button_show name="button" ]

[evt name="event_button" target="*jump_start" ]

*jump_start
{evt.caller_name}がクリックされました


イベント関連




[evt_remove]イベントの削除

登録しておいたイベントを削除し、無効化します。

パラメータ名必須 デフォルト説明
name × イベントを無効にするnameを指定します
tag × 指定タグに対してまとめてイベントを無効にすることができます

サンプルコード


イベント関連




[evt_stop]イベントの一時無効化

すべてのイベントを一時無効化します。
例えばボタンが押された後、処理が完了するまで他のボタンを押してほしくない場合などに指定することができます。

パラメータ名必須 デフォルト説明
指定できるパラメータはありません

サンプルコード


イベント関連




[evt_resume]イベントの再開

evt_stopで無効化していたイベントを再度有効にします。

パラメータ名必須 デフォルト説明
name × イベントを無効にするnameを指定します
tag × 指定タグに対してまとめてイベントを無効にすることができます

サンプルコード


イベント関連




[show]画面上のオブジェクトの表示

image_show chara_show text_show の短縮形です。
すべての要素に適応できます。

パラメータ名必須 デフォルト説明
name × 識別するための名前を指定します
tag × 識別するためのタグを指定します
x × 中心からのx位置を指定します
y × 中心からのy位置を指定します
z × 中心からのz位置を指定します
time × 1 表示にかかる時間を秒で指定します。デフォルトは1(秒)です
wait × true 表示の完了を待つかどうかを true false で指定します。デフォルトは true です。
type × linear 表示のされ方を指定できます。デフォルトはlinear です。

サンプルコード
[image_new name="logo" tag=system ]
@show name="logo"

イメージ関連




[hide]オブジェクトを非表示にします

image_hide text_hide chara_hide の短縮形です
すべての要素について非表示に出来ます。

パラメータ名必須 デフォルト説明
name × 識別するための名前を指定します
tag × 識別するためのタグを指定します
time × 1 非表示にかかる時間を秒で指定します。デフォルトは1(秒)です
wait × true 非表示の完了を待つかどうかを true false で指定します。デフォルトは true です。
type × linear 非表示のされ方をしていできます。デフォルトはlinear です。

サンプルコード
;name ロゴを表示
[show name=logo ]

;tagを指定して複数画像を一斉に表示することも可能
[hide name=logo time=3 wait=false]


イメージ関連




[remove]オブジェクトの削除

image_remove chara_remove text_remove の短縮形です
オブジェクトをゲーム上から削除します

パラメータ名必須 デフォルト説明
name × 削除するimageをimage_new の時に設定したnameを指定します。all と入力することですべてのイメージを削除することができます。
tag × 削除するimageをimage_new の時に設定したtagを指定します。指定したtagが振られているイメージを一括削除できます

サンプルコード
[remove name="logo"]

イメージ関連




[image_new]イメージの定義

イメージを新しく定義します

パラメータ名必須 デフォルト説明
name 識別するための名前を指定します
storage 画像ファイルを指定します
tag × タグ名を指定できます
layer × Default 表示させるレイヤを指定します。画面の背面から順に、background,Default,character,message,front が指定できます。デフォルトはDefaultが指定されます
sort × 0 同一レイヤ内の表示順を整数で指定してください
x × 0 中心からのx位置を指定します
y × 0 中心からのy位置を指定します
z × -3.2 中心からのz位置を指定します
scale_x × 1 X方向へのイメージの拡大率を指定します。
scale_y × 1 Y方向へのイメージの拡大率を指定します。
scale_z × 1 Z方向へのイメージの拡大率を指定します。
scale × イメージの拡大率を指定します。つまり2と指定すると大きさが2倍になります

サンプルコード
[image_new name="logo" tag=system ]

イメージ関連




[image_pos]イメージの表示位置設定

image_newで定義した画像の表示位置を指定することができます。

パラメータ名必須 デフォルト説明
name 識別するための名前を指定します
x × 中心からのx位置を指定します
y × 中心からのy位置を指定します
scale_x × X方向へのイメージの拡大率を指定します。
scale_y × Y方向へのイメージの拡大率を指定します。
scale × イメージの拡大率を指定します。つまり2と指定すると大きさが2倍になります

サンプルコード
[image_pos name="logo" x=2.5 y=1.5 ]

イメージ関連




[image_show]イメージを表示します。

image_newで定義した画像を表示します

パラメータ名必須 デフォルト説明
name × 識別するための名前を指定します
tag × 識別するためのタグを指定します
x × 中心からのx位置を指定します
y × 中心からのy位置を指定します
z × 中心からのz位置を指定します
time × 1 表示にかかる時間を秒で指定します。デフォルトは1(秒)です
wait × true 表示の完了を待つかどうかを true false で指定します。デフォルトは true です。
type × linear 表示のされ方を指定できます。デフォルトはlinear です。

サンプルコード
;name ロゴを表示
[image_show name=logo ]

;tagを指定して複数画像を一斉に表示することも可能
[image_show tag=logo time=3 wait=false]


イメージ関連




[image_hide]イメージを非表示にします

image_newで定義した画像を非表示にします。

パラメータ名必須 デフォルト説明
name × 識別するための名前を指定します
tag × 識別するためのタグを指定します
time × 1 非表示にかかる時間を秒で指定します。デフォルトは1(秒)です
wait × true 非表示の完了を待つかどうかを true false で指定します。デフォルトは true です。
type × linear 非表示のされ方をしていできます。デフォルトはlinear です。

サンプルコード
;name ロゴを表示
[image_show name=logo ]

;tagを指定して複数画像を一斉に表示することも可能
[image_hide name=logo time=3 wait=false]


イメージ関連




[image_face]イメージの表情を変更できます

image_faceを登録しておくことで、以後は表情名を指定するだけで画像を切替える事ができるようになります。

パラメータ名必須 デフォルト説明
name 識別するための名前を指定します
face image_face で指定した表情名を指定できます
storage 画像ファイル名を直接していできます。フォルダはdata/images/image 以下を参照します。

サンプルコード
;name ロゴを表示
[image_show name=logo ]

;画像の表情を登録
[image_face face=logo2 storage="other_logo"]

;faceを指定するだけで画像の切り替えが可能になる
[image_mod name=logo face=logo2]

;chara_new で指定した画像はdefault という名前で指定できます
[image_mod name=logo face=default ]



イメージ関連




[image_mod]イメージを変更します

image_newで定義した画像の情報を変更します。

パラメータ名必須 デフォルト説明
name 識別するための名前を指定します
face × image_face で指定した表情名を指定できます
storage × 画像ファイル名を直接していできます。フォルダはdata/images/image 以下を参照します。
time × 1 変更にかかる時間を秒で指定します。デフォルトは1(秒)です
wait × true 変更を待つかどうかを true false で指定します。デフォルトは true です。
type × linear 変更のされ方を指定できます。デフォルトはlinear です。

サンプルコード
;name ロゴを表示
[image_show name=logo ]

;tagを指定して複数画像を一斉に表示することも可能
[image_mod name=logo storage="other_logo"]


イメージ関連




[image_remove]イメージの削除

イメージ定義を削除します。
使用しなくなったイメージを削除することにより
メモリを節約することでゲームが快適に動作することができます。
このタグでキャラクターを削除した場合、再度表示するときは
新たに[image_new]する必要があります。

パラメータ名必須 デフォルト説明
name × 削除するimageをimage_new の時に設定したnameを指定します。all と入力することですべてのイメージを削除することができます。
tag × 削除するimageをimage_new の時に設定したtagを指定します。指定したtagが振られているイメージを一括削除できます

サンプルコード
[image_remove name="logo"]

イメージ関連




[live2d_new]Live2Dモデル定義

Live2Dモデルを新しく定義します。

パラメータ名必須 デフォルト説明
name 識別するための名前を指定します
storage 表示させるモデルのprefabを指定します
tag × タグ名を指定できます
layer × Default 表示させるレイヤを指定します。画面の背面から順に、background,Default,character,message,front が指定できます。デフォルトはDefaultが指定されます
sort × 0 同一レイヤ内の表示順を整数で指定してください
x × 0 中心からのx位置を指定します
y × 0 中心からのy位置を指定します
z × -3.2 中心からのz位置を指定します
scale × 3 Live2Dモデルの表示サイズを指定できます。つまり2と指定すると大きさが2倍になります

サンプルコード

;Live2Dモデルの定義
[live2d_new name="モデルID" storage="Hal_prefab" x=1 y=2 scale=6]

Live2D関連




[live2d_pos]Live2Dモデルの表示位置設定

live2d_newで定義したLive2Dモデルの表示位置を指定することができます。

パラメータ名必須 デフォルト説明
name 識別するための名前を指定します
x × 中心からのx位置を指定します
y × 中心からのy位置を指定します

サンプルコード
[live2d_pos name="hal" x=0 y=0.5 ]

Live2D関連




[live2d_show]Live2Dモデルを表示します。

live2d_newで定義したLive2Dモデルを表示します

パラメータ名必須 デフォルト説明
name × 識別するための名前を指定します
tag × 識別するためのタグを指定します
x × 中心からのx位置を指定します
y × 中心からのy位置を指定します
z × 中心からのz位置を指定します
time × フェードイン表示にかかる時間を指定できます

サンプルコード

;ロゴを表示
[live2d_show name=logo ]

;tagを指定して複数画像を一斉に表示することも可能
[live2d_show name="モデルID"]

Live2D関連




[live2d_hide]Live2Dモデルを非表示にします

live2d_newで定義したLive2Dモデルを非表示にします。

パラメータ名必須 デフォルト説明
name × 識別するための名前を指定します
tag × 識別するためのタグを指定します
time × フェードアウトにかかる時間を指定できます

サンプルコード
[live2d_remove name="モデルID"]

Live2D関連




[live2d_remove]Live2Dモデルの削除

live2d_newで定義したLive2Dモデルを削除します。

パラメータ名必須 デフォルト説明
name 削除するテキストオブジェクト名 all と入力することですべてのキャラクターを削除することができます。

サンプルコード
[live2d_remove name="hal"]

Live2D関連




[live2d_motion]Live2Dモデルのモーション再生

Live2Dモデルのモーションを再生します。

パラメータ名必須 デフォルト説明
name モーションを適用したいオブジェクト名を指定します。all と入力することですべてのキャラクターをモーションすることができます。
storage モーションファイル名を指定してください
idle × アイドリング有無('ON'など文字列を渡すとアイドリングさせます)

サンプルコード
[live2d_motion name="モデルID" storage="haru_m_02.mtn"]

Live2D関連




[skipstart]スキップ開始

メッセージのスキップを開始します。
skipstopタグに到達するか
プレイヤーが画面をクリックするまで自動的に読み進みます。

パラメータ名必須 デフォルト説明
指定できるパラメータはありません

サンプルコード

ここまでは通常通り表示[p]
[skipstart]
ここからスキップが開始されます


ゲーム操作関連




[skipstop]スキップ停止

メッセージのスキップ状態の場合
強制的にメッセージスキップを停止することができます。
スキップさせたくない場面の直前に配置しておくと良いかと思います。

パラメータ名必須 デフォルト説明
指定できるパラメータはありません

サンプルコード

[skipstart]
ここはスキップ[p]
[skipstart]
ここでスキップが停止される。

ゲーム操作関連




[savesnap]セーブスナップの作製

このタグに到達した時点でゲームの状態を
savesnap.savというファイルに格納することができます。
後に[save]を実行した時にこのsavesnapの状態がセーブされます。

gamesleepタグを使った場合は暗黙的にsavesnapが実行されます。
デフォルトのセーブ機能ではgamesleep時に保存しておいたデータを遷移先のセーブ画面で保存するという実装になっています。
セーブ機能をカスタマイズする場合、このsavesnapをよく理解してください

パラメータ名必須 デフォルト説明
指定できるパラメータはありません

サンプルコード

[savesnap]
セーブ状態を格納。

;上記のsavesnapタグ時点のデータがsave_0として保存される
[save name="save_0"]


データ関連




[sleepgame]ゲームの一時停止

このタグに到達した時点でゲームの状態を
gametmpとsavesnapに保存した上で、他のシナリオへ移動することができます。
そして遷移先で[awakegame]が実行されたらgametmpから状態を再現してゲームに復帰できます。

このタグは本流のゲームから一時的に画面を遷移したい場合に非常に強力に機能します。

例えば、ゲームの途中でコンフィグの設定を行いたい場合などは
sleepgameで進行状態を保持した上で、コンフィグ画面に移動します。[awakegame]タグでゲームに復帰します

パラメータ名必須 デフォルト説明
file × ゲームを中断して処理を始めるファイル名を記述します。省略された場合は、現在のファイル名と解釈されます
target × ジャンプする先のラベル名を指定できます。省略されている場合は先頭位置からと解釈されます
savesnap × true trueを指定するとゲームを一時停止する直前の状態をsavesnapに保存します

サンプルコード

[sleepgame file="libs/save" target="*savestart"]

遷移先でawakegameが実行されるとここに戻ってくる

データ関連




[awakegame]一時停止から復帰


[gamesleep]タグで一時していたゲームを再開します。

パラメータ名必須 デフォルト説明
指定できるパラメータはありません

サンプルコード

;gamesleep状態から復帰
[awakegame]

データ関連




[autostart]オートメッセージ

一定間隔でストーリーを読み進める事ができます。
画面クリックでオートモードがキャンセルされます。

パラメータ名必須 デフォルト説明
time × 3 何秒間隔で自動的にストーリーが進むかを設定することができます。

サンプルコード

[autostart]
ここからは[p]
一定間隔で[p]
自動的に読み進まれます[p]

データ関連




[delay]メッセージ速度

メッセージの表示速度を調整できます。
うまく活用することで効果的な演出を行うことが可能です。

一度だけ有効でクリックで元の速度に戻ります。

パラメータ名必須 デフォルト説明
speed 0.02 1文字が表示される秒数を指定します。

サンプルコード

ここは通常通りの速度で表示されます[p]
[delay speed="0.1" ]
ここは文字速度が遅くなって表示されます[p]
]

メッセージ関連




[font]メッセージフォント設定

メッセージの色とサイズを変更することができます。
設定は[resetfont]タグに到達するまで有効です。

色についてはHTMLなどで使用する形式を使用でき
あらゆる色を設定することが可能です
色コードについては色見本が参考になるかと思います

パラメータ名必須 デフォルト説明
color × 色コードを指定します。16進数形式で指定してください(例)#FFFFFF

サンプルコード

;色を変更します。シャープはあっても無くても良いです。
[font color=#EE1919 ]
ここは色が変更されたメッセージに鳴ります

[resetfont]
ここはもとの色に戻って表示されます。

メッセージ関連




[fontreset]メッセージ設定のリセット


[font]タグで設定した内容を取り消して、標準の状態に戻します。

パラメータ名必須 デフォルト説明
指定できるパラメータはありません

サンプルコード

;色を変更します。シャープはあっても無くても良いです。
[font color=#EE1919 ]

[resetfont]
ここはもと色に戻って表示されます

メッセージ関連




[save]セーブ

このタグの場所でセーブを作成します
セーブデータはsavesnapから保存されます。
savesnapは[savesnap]タグを明示して作成するか
[gamesleep]を実行したタイミングで生成されます。

パラメータ名必須 デフォルト説明
name セーブファイル名を指定します

サンプルコード

[save name=save_01]

データ関連




[load]ロード

セーブしてあったデータをロードします。

パラメータ名必須 デフォルト説明
name ロードするセーブファイル名を指定します

サンプルコード
;現在のゲーム状態をすべて破棄してセーブデータを読み込む
[load name="save_01"]

データ関連




[saveloop]セーブデータの列挙

これはセーブ画面の制作で使用する機能です。
セーブファイルの情報を順番に列挙してループ処理することができます。

必ず対になる[end_saveloop]タグが必要です。

configファイルで指定されている最大セーブスロット数まで、0から順に列挙していきます。
save_0 save_1 save_2 … というセーブファイルを列挙していく

ループ毎にsave変数にデータが格納されます。
取得できる情報は

save.title : セーブタイトル
save.date :セーブ日時
save.description:セーブ説明文字列
save.name:セーブファイル名(ロード時に指定する名前でもある)

save.max_num:セーブスロットの最大数
save.index:現在のセーブインデックス
save.max_index:このページの最大インデックス
save.loop_start_component_index:


パラメータ名必須 デフォルト説明
num × 5 ループ回数
page × 0 ページ。つまり、numが5でpageが1なら5〜10までのセーブデータがループで検索されます

サンプルコード


[saveloop]

;セーブデータを表示
[trace exp="save"]

;セーブデータを表示し、セーブボタンを配置
@image_new storage="save" layer=ui name="{save.name}" tag="save_button" x=4 y={tmp.image_y} scale=1.5
@text_new name="text_date_{save.name}" anchor="MiddleLeft" cut=20 val="{save.date}" tag="samune" x=0.27 y={tmp.text_date_y}
@text_new name="text_{save.name}" anchor="MiddleLeft" cut=20 val="{save.title}" tag="samune" x=0.27 y={tmp.text_y}

[end_saveloop]



データ関連




[end_saveloop]セーブデータの列挙終了


[saveloop]タグの終端を表します

パラメータ名必須 デフォルト説明
指定できるパラメータはありません

サンプルコード



データ関連




[autosave]オートセーブ


オートセーブを実行します
これにより次回起動時にプレイヤーは
この地点からゲームを再開することができるようになります。

スマートフォンなどの場合、中断と再開が多いので
定期的にautosaveを挟んでおいて、再開できるようにしておく設計が望ましいでしょう。

セーブデータはautosaveという名前で保存されます
ロード時はnameにautosaveと指定することで状態を復元することが可能です

パラメータ名必須 デフォルト説明
指定できるパラメータはありません

サンプルコード

[autosave]

データ関連




[get_autosave]オートセーブの取得


オートセーブで保存されているデータを
変数に格納して使用することができます。

パラメータ名必須 デフォルト説明
var auto オートセーブのデータを格納する変数名を指定

サンプルコード

;autoという変数にオートセーブのデータを代入
@get_autosave var=auto

;オートセーブされたデータが存在するなら
[if exp="{auto.date}!=''"]

オートセーブファイル:{auto.name}[r]
オートセーブ日時:{auto.date}[r]
オートセーブタイトル:{auto.title}[r]

データ関連




[sd_new]3Dモデル定義


外部ツールで作成した3DモデルやMMDなどのデータをゲームに表示させます。
対応形式はfbx形式です

3Dモデルデータはsd/fbx フォルダ以下に配置してください

パラメータ名必須 デフォルト説明
name 識別するための名前を指定します
storage 表示するfbxファイルを指定します。ファイルパスはsd/fbxフォルダ以下に配置してください
tag × タグ名を指定できます
layer × Default 表示させるレイヤを指定します。画面の背面から順に、background,Default,character,message,front が指定できます。デフォルトはDefaultが指定されます
sort × 0 同一レイヤ内の表示順を整数で指定してください
x × 0 中心からのx位置を指定します
y × 0 中心からのy位置を指定します
z × 6.66 中心からのz位置を指定します
scale_x × 1 X方向への3Dモデルの拡大率を指定します。
scale_y × 1 Y方向への3Dモデルの拡大率を指定します。
scale_z × 1 Z方向への3Dモデルの拡大率を指定します。
scale × 5 3Dモデルの拡大率を一律していできます。つまり2を指定するとモデルが2倍の大きさになります。
rot_x × 0 3DモデルのX軸角度を指定します。0〜360の間で指定します
rot_y × 180 3DモデルのY軸角度を指定します。0〜360の間で指定します
rot_z × 0 3DモデルのZ軸角度を指定します。0〜360の間で指定します

サンプルコード

;3Dモデルの定義
@sd_new name=miku storage="latmiku" x=5.37 y=-5.23

;3Dモデルを表示
@sd_show name=miku


3Dモデル関連




[sd_show]3Dモデル表示

sd_newで定義した3Dモデルを画面に表示します

パラメータ名必須 デフォルト説明
name × 識別するための名前を指定します
tag × 識別するためのタグを指定します
x × 中心からのx位置を指定します
y × 中心からのy位置を指定します
z × 中心からのz位置を指定します

サンプルコード

;3Dモデルの定義
@sd_new name=miku storage="latmiku" x=5.37 y=-5.23

;3Dモデルを表示
@sd_show name=miku


3Dモデル関連




[sd_remove]3Dモデル削除

sd_newで定義した3Dモデルを削除します。
使用しなくなった3Dモデルはこのタグでこまめに削除することで
動作を軽くすることができます。

パラメータ名必須 デフォルト説明
name × 識別するための名前を指定します
tag × 識別するためのタグを指定します

サンプルコード

;3Dモデルの定義
@sd_new name=miku storage="latmiku" x=5.37 y=-5.23

;3Dモデルを表示
@sd_show name=miku

;3Dモデルの削除
@sd_remove name=miku


3Dモデル関連




[sd_hide]3Dモデル退場

画面に表示している3Dモデルを非表示にします。
sd_hideタグで非表示にしたキャラクターは
いつでもsd_showで再登場させることができます。

パラメータ名必須 デフォルト説明
name × 識別するための名前を指定します
tag × 識別するためのタグを指定します

サンプルコード

;3Dモデルの定義
@sd_new name=miku storage="latmiku" x=5.37 y=-5.23

;3Dモデルを表示
@sd_show name=miku

;3Dモデルの非表示
@sd_hide name=miku

;3Dモデルを再度表示
@sd_show name=miku


3Dモデル関連




[sd_anim]3Dモデルモーション再生

画面に表示している3Dモデルにモーションを設定します。
モーションは予めMecanimで設定しておき、このタグからフラグを制御することで
3Dモデルに好きなタイミングでモーションを実行させることができます。

パラメータ名必須 デフォルト説明
name 識別するための名前を指定します
tag × 識別するためのタグを指定します
state Mecanimに設定されている変数にtrueを設定します。Mecahimではここで指定するステートのON OFFによって状態を変更するように設定します
condition × true stateで指定するステートをtrue or falseで指定することができます。

サンプルコード

;3Dモデルの定義
@sd_new name=miku storage="latmiku" x=5.37 y=-5.23

;3Dモデルを表示
@sd_show name=miku

;3Dモデルにモーションを適応 NyanDanceをtrueにする
@sd_anim name=miku state="NyanDance"


3Dモデル関連




[macro]マクロ定義


マクロ記述を開始します。新しいタグを定義することが出来ます。
このタグから、endmacro タグまでにある文章やタグは
name 属性で指定されたタグとして登録され、以後使用できるようになります。

マクロには値を渡すことができます。渡された変数には mp という変数に格納され、アクセスすることが可能です。

パラメータ名必須 デフォルト説明
name ラベル名を指定してください

サンプルコード



[macro name="newtag"]
新しいタグです。[p]
{mp.arg1}という値が渡されました。
[endmacro]

[newtag arg1="テスト"]

シナリオ制御




[endmacro]マクロの終端


マクロ終了を表します

パラメータ名必須 デフォルト説明
指定できるパラメータはありません

サンプルコード


[macro name="newtag"]
新しいタグです。[p]
{mp.arg1}という値が渡されました。
[endmacro]


シナリオ制御




[jump]別のシナリオ位置へジャンプ

このタグの場所に到達するとfileとtargetで指定された場所へジャンプします

ジャンプ命令はcallスタックに残りません。つまり、return で指定位置に戻ることができません。
jump先では標準でcaller_index と caller_file という変数が格納されています。
これは、jumpした地点のファイルとindexを保持しています。
mp.caller_index と mp.caller_file を使うことで元の位置に戻ることが可能です

jumpには好きなパラメータを渡すことが可能です。
jump先ではmp.arg1 のような形で変数にアクセスすることが可能です。

scene=new とすることで、全く新しいシーンを新たに生成した上でジャンプすることができます。
まっさらな状態になるので、もう一度背景やキャラクター情報などを定義する必要があります。

場面の切り替わりなどではscene=newでjumpすることにより、不要なデータを一掃することで
健全な状態を保ってゲームを進めることができるできます。
ですので、定期的にscene=new でジャンプを行うことをオススメします。


パラメータ名必須 デフォルト説明
file × 移動するシナリオファイル名を指定します。省略された場合は現在のシナリオファイルと見なされます
target × ジャンプ先のラベル名を指定します。省略すると先頭から実行されます
index × 内部的に保持しているゲーム進行状況の数値を指定することができます。
scene × new を指定すると、新しくシーンを作成した上でジャンプします。

サンプルコード

[jump taget=*test]
ここは無視される[p]

*test

ここにジャンプする。

シナリオ制御




[call]サブルーチンの呼び出し

指定されたシナリオファイルの指定されたラベルで示される サブルーチンを呼び出します。
呼び出されたサブルーチンは、 return タグで 呼び出し元や任意の場所に戻ることができます


パラメータ名必須 デフォルト説明
file × 呼び出したいサブルーチンのあるのシナリオファイルを 指定します。省略すると、現在 のシナリオファイル内であると見なされます
target × 呼び出すサブルーチンのラベルを指定します。省略すると、ファイルの先頭から実行されます。

サンプルコード

[call taget=*test]
サブルーチンが終わるとここに戻ってきます[p]

*test

ここにジャンプする。

[return]

シナリオ制御




[return]サブルーチンから戻る

サブルーチンから呼び出し元に戻ります。
return時にfileとtargetを指定することでスタックを消費した上で
任意の場所に戻ることもできます。

パラメータ名必須 デフォルト説明
file × サブルーチンの呼び出し元に戻らずに、指定したファイルへ移動することできます。
target × サブルーチンの呼び出し元に戻らずに、指定したラベルへ移動することできます。

サンプルコード

[call taget=*test]
サブルーチンが終わるとここに戻ってきます[p]

*test

ここにジャンプする。

[return]

シナリオ制御




[calc]数式の評価

expで示された式を評価します。変数への値の代入などに使用されます。
文字列はこのタグでは扱うことはできません。文字列は[flag]タグを使用します

パラメータ名必須 デフォルト説明
exp 数式を指定します

サンプルコード


[calc exp="f.test=500"]
;↑変数 test に数値を代入している

[calc exp="sf.test2=400"]
;↑システム変数 test に数値を代入している

[calc exp="f.test2={f.test}*3"]
;↑ゲーム変数 test2 に ゲーム変数 test の 3 倍の数値を代入している

{f.test2}[p]


システム関連




[flag]文字列の評価

文字列を扱うことができます。

パラメータ名必須 デフォルト説明
exp 文字式を指定します

サンプルコード

[flag exp="f.test=ゆうこ"]
;↑変数 test に文字列を代入している

はじめまして{f.test}さん。[p]
;はじめましてゆうこさん。と表示される

;文字の連結
[flag exp="f.str = はじめまして{f.test}さん" ]
{f.str}
;はじめましてゆうこさん。と表示される

システム関連




[emb]変数の展開


メッセージ中に変数の中身を展開して表示することができます。
省略形として{ } で括る方法もあります。

パラメータ名必須 デフォルト説明
exp 評価する変数を格納します。

サンプルコード


[flag exp="f.value1='変数の値だよ~ん'"]
とどこかで書いておいて、
[emb exp="f.value1"]
と書くと、この emb タグが 変数の値だよ~ん という内容に置き換わります。

メッセージ関連




[if]条件分岐


式を評価し、その結果が true ( または 0 以外 ) ならば、 elsif・else・endif のいずれかまでにある
文章やタグを実行し、そうでない場合は無視します。

パラメータ名必須 デフォルト説明
exp 評価する式を指定します。この式の結果が false ( または 0 な らば、elsif・else・endif タグまでの文章やタグが無視されます。

サンプルコード


; 例1
[if exp="false"]
ここは表示されない
[else]
ここは表示される
[endif]

; 例2
[if exp="false"]
ここは表示されない
[elsif exp="false"]
ここは表示されない
[else]
ここは表示される
[endif]

; 例3
[if exp="false"]
ここは表示されない
[elsif exp="true"]
ここは表示される
[else]
ここは表示されない
[endif]

; 例4
[if exp="true"]
ここは表示される
[elsif exp="true"]
ここは表示されない
[else]
ここは表示されない
[endif]


シナリオ関連




[elsif]それまでの if の中身が実行されていなかったときに、条件付きで実行


if タグと endif タグの間で用いられます。 それまでの if タグまたは elsif タグの中身がひとつも実行されていないときに
式を評価し、その結果が真ならば elsif から次の elsif・else・endif までの間を実行します。
使い方の例については、if タグの項目を参照してください。

パラメータ名必須 デフォルト説明
exp 評価する変数を格納します。

サンプルコード


シナリオ関連




[else]if の中身が実行されなかったときに実行


if タグもしくは elsif タグ と endif タグの間で用いられます。 if または elsif ブロックの中身がひとつも実行されていないとき、 else から endif までの間を実行します。
使い方の例については、if タグの項目を参照してください。

パラメータ名必須 デフォルト説明
指定できるパラメータはありません

サンプルコード

シナリオ関連




[endif]if文を終了します


if文を終了します。必ずif文の終わりに記述する必要があります

パラメータ名必須 デフォルト説明
指定できるパラメータはありません

サンプルコード


シナリオ関連




[s]ゲームを停止する


シナリオファイルの実行を停止します。
選択肢表示した直後などに配置して利用する方法があります。

パラメータ名必須 デフォルト説明
指定できるパラメータはありません

サンプルコード

テストこの後はジャンプなどでsを飛び越える処理を記述して追う必要があります[p]
@jump target=label1

[s]

*label1
ジャンプで[s]を飛び越える

シナリオ関連




[tag_default]デフォルトでタグ名を付与する


以降のタグにデフォルトでtagパラメータを付与することができます。
[reset_tag_default]を行うまでtagが付与されるので注意してください。

パラメータ名必須 デフォルト説明
tag 付与するタグ名を指定します

サンプルコード

;以後の命令にcharaというtag属性を付与する

@tag_default tag="chara"
[chara_new name="hiro1" storage="mayuri_clothes_earnest" scale="1.2"]
[chara_new name="hiro2" storage="mayuri_clothes_lonely"]
[chara_new name="hiro3" storage="senior01_looking_away"]
@reset_tag_default

;タグを付与したキャラクターを一度に表示する
@chara_show tag="chara"


シナリオ関連




[reset_tag_default]デフォルトタグ設定を解除する


[default_tag]の効果を無効にします

パラメータ名必須 デフォルト説明
指定できるパラメータはありません

サンプルコード


シナリオ関連




[hidemessage]メッセージ非表示


メッセージウィンドウを非表示にします。
[showmessage]を明示的に実行するまで表示されません。

パラメータ名必須 デフォルト説明
指定できるパラメータはありません

サンプルコード

[hidemessage]

[wait time=5 ]

[showmessage]
シナリオ再開

システム関連




[showmessage]メッセージ表示


メッセージウィンドウを表示します。

パラメータ名必須 デフォルト説明
指定できるパラメータはありません

サンプルコード

[hidemessage]

[wait time=5 ]

[showmessage]
シナリオ再開

システム関連




[trace]変数の内容確認


変数の中身をデバックコンソールで確認することができます。

パラメータ名必須 デフォルト説明
exp × 確認したい変数名を指定します。

サンプルコード


[calc exp="tmp.val=2"]
[flag exp="tmp.name=シケモク"]

;tmpの中身を確認できる
[trace exp="tmp"]

;結果↓がデバッグコンソールに表示される
;[trace]tmp
;val=2
;name=シケモク

システム関連




[talk_name]発言者欄の変更


発言者欄の名前を変更します。
chara_newでjnameを定義している場合はその値が採用されます。

このタグは省略形が用意されています
以下の2つは同じ意味になります。

#yuko

[talk_name val=yuko ]


パラメータ名必須 デフォルト説明
val × 名前を表示します。キャラクター情報と絡めたい場合はchara_newした時のnameを指定してください。

サンプルコード

@talk_name val=優子

以下のようにも書けます

#優子
優子がしゃべってます。

@talk_name val=""
消したい場合は空白を指定します

システム関連




[wait]ウェイトを入れる


ウェイトを入れます。time属性で指定した時間、操作できなくなります。

パラメータ名必須 デフォルト説明
time 停止する時間を秒で指定します

サンプルコード

;2.5秒間 処理を停止します
[wait time=2.5]

システム関連




[web]Webページヘジャンプします。


ゲーム中にブラウザを開いてサイトを開きます
スマホアプリの場合、一時的にゲームを中断してブラウザが起動します

パラメータ名必須 デフォルト説明
url 移動したいURLをhttpから指定します

サンプルコード

;やほーを訪問します
[web url="http://yahoo.co.jp"]

その他




[clearvar]変数を削除。


変数を削除します。


パラメータ名必須 デフォルト説明
name 削除する変数名を指定してください。

サンプルコード

[calc exp="tmp.val=2"]
[flag exp="tmp.name=シケモク"]

;tmpの中身を確認できる
[trace exp="tmp"]

;tmp変数をすべて初期化します
[clearvar name="tmp"]

システム関連




[showlog]バックログ表示


バックログを表示します。

パラメータ名必須 デフォルト説明
指定できるパラメータはありません

サンプルコード

[showlog]

システム関連




[text_new]テキストの定義

画面に表示するテキストを新しく定義します

■anchor に指定できる値
LowerCenter
LowerLeft
LowerRight
MiddleCenter
MiddleLeft
MiddleRight
UpperCenter
UpperLeft
UpperRight
MiddleCenter

■alignment に指定できる値
Left
Right
Center

パラメータ名必須 デフォルト説明
name 識別するための名前を指定します
val 表示するテキスト文字列を指定します
tag × タグ名を指定できます
layer × Default 表示させるレイヤを指定します。画面の背面から順に、background,Default,character,message,front が指定できます。デフォルトはDefaultが指定されます
sort × 0 同一レイヤ内の表示順を整数で指定してください
x × 0 中心からのx位置を指定します
y × 0 中心からのy位置を指定します
z × -3.2 中心からのz位置を指定します
scale × 1 文字の拡大率を指定します。つまり2と指定すると大きさが2倍になります
anchor × MiddleCenter テキストの横位置を指定できます
color × FFFFFF テキストの色を16進数形式で指定します
fontsize × 14 フォントサイズを指定します
cut × 数値を指定します。指定した文字数でカットします。

サンプルコード
@text_new name="test" anchor="MiddleLeft" val="テキスト内容" x=0.227 y=0.205

;テキストの表示
@text_show name="test"

;imageタグでも表示することができます
@image_show name="test"


テキスト関連




[image_pos]テキストの表示位置設定

text_newで定義したテキストの表示位置を指定することができます。

パラメータ名必須 デフォルト説明
name 識別するための名前を指定します
x × 中心からのx位置を指定します
y × 中心からのy位置を指定します

サンプルコード
[text_pos name="logo" x=0 y=0.5 ]

テキスト関連




[text_show]テキストを表示します。

text_newで定義した画像を表示します

パラメータ名必須 デフォルト説明
name × 識別するための名前を指定します
tag × 識別するためのタグを指定します
x × 中心からのx位置を指定します
y × 中心からのy位置を指定します
z × 中心からのz位置を指定します
time × 1 表示にかかる時間を秒で指定します。デフォルトは1(秒)です
wait × true 表示の完了を待つかどうかを true false で指定します。デフォルトは true です。
type × linear 表示のされ方を指定できます。デフォルトはlinear です。

サンプルコード

;ロゴを表示
[text_show name=logo ]

;tagを指定して複数画像を一斉に表示することも可能
[text_show tag=logo time=3 wait=false]

テキスト関連




[text_hide]テキストを非表示にします

text_newで定義した画像を非表示にします。

パラメータ名必須 デフォルト説明
name × 識別するための名前を指定します
tag × 識別するためのタグを指定します
time × 1 非表示にかかる時間を秒で指定します。デフォルトは1(秒)です
wait × true 非表示の完了を待つかどうかを true false で指定します。デフォルトは true です。
type × linear 非表示のされ方をしていできます。デフォルトはlinear です。

サンプルコード
;name ロゴを表示
[image_show name=logo ]

;tagを指定して複数画像を一斉に表示することも可能
[image_hide name=logo time=3 wait=false]


テキスト関連




[text_mod]テキストを変更します

text_newで定義したテキストの情報を変更します。

パラメータ名必須 デフォルト説明
name 識別するための名前を指定します
val × テキスト文字列を入力します
time × 1 変更にかかる時間を秒で指定します。デフォルトは1(秒)です
wait × true 変更を待つかどうかを true false で指定します。デフォルトは true です。
type × linear 変更のされ方を指定できます。デフォルトはlinear です。

サンプルコード
;ロゴを表示
[text_show name=logo ]

[text_mod name=logo val="変更後テキスト"]


テキスト関連




[text_remove]テキストの削除

テキスト定義を削除します。

パラメータ名必須 デフォルト説明
name 削除するテキストオブジェクト名 all と入力することですべてのキャラクターを削除することができます。

サンプルコード
[text_remove name="yuko"]

テキスト関連


■アニメーション関連

■オーディオ関連

■イメージ関連

■ボタン関連

■キャラクター関連

■クリッカブル関連

■メッセージ関連

■イベント関連

■Live2D関連

■ゲーム操作関連

■データ関連

■3Dモデル関連

■シナリオ制御

■システム関連

■シナリオ関連

■その他

■テキスト関連